use v6;

my $requested_date = Date.today;
if @*ARGS[0] {
    $requested_date = Date.new(@*ARGS[0]);
}

# first, obtain the current calendar from the Geneva web site
run("curl -s http://www.ville-geneve.ch/plan-ville/sports/piscine-vernets/ -o /tmp/webpage.html");

my $htmldoc = open "/tmp/webpage.html", :r;

my $filetodownload;
for $htmldoc.lines -> $line {
    if $line ~~ / 'href="' (<[a..z A..Z \/ \_]>* 'Horaires' .*? ) '"' / {
	$filetodownload = $/[0];
    }
}
close $htmldoc;
unless $filetodownload { die  "Could not find current calendar file."; }

# Now, download and convert the PDF calendar
my $pdfname = $filetodownload.split(/\//)[* - 1];

if !($pdfname.IO ~~ :e) {
    # Download pdf from site
    run("curl -s -O http://www.ville-geneve.ch$filetodownload");
}

run("pdftotext -enc UTF-8 $pdfname /tmp/horaire.txt");

# Open the converted PDF
my $input = open "/tmp/horaire.txt", :r;

# Be liberal with the accents, so we accept months according to their
# first few letters
my @month_starts = <jan fe mar av mai juin juil ao sep oct nov d>;

my @current_dates;

my $collect_mode = <both>;

my Int $i = 0;

my %vernets;
my %varembe;

for $input.lines -> $line {
    when $line ~~ / ^^
Semaine \s+ du \s+
$<startday>=(\d+) \s+
$<startmonth>=((\w+) \s+)?
$<startyear>=((\d+) \s+)?
au \s+
$<endday>=(\d+) \s+
$<endmonth>=(\w+) \s+
$<endyear>=(\d+) 
$$/ {
        my $startmonth = $<startmonth>;
	unless $startmonth {
	    $startmonth = $<endmonth>;
	}
	my $startyear = $<startyear>;
	unless $startyear {
	    $startyear = $<endyear>;
	}
	my $startmonthindex = 0;
	my $endmonthindex = 0;
	for @month_starts Z 1 .. Inf -> $mname, $index {
	    if $startmonth.substr(0,$mname.chars) eq $mname {
		$startmonthindex = $index;
	    }
	    if $<endmonth>.substr(0,$mname.chars) eq $mname {
		$endmonthindex = $index;
	    }
	}
	my $startdate = Date.new("$startyear",$startmonthindex,"$<startday>");
	my $enddate = Date.new("$<endyear>",$endmonthindex,"$<endday>");
	@current_dates = $startdate .. $enddate;
    }
    when $line ~~ /PISCINE .* PISCINE .*/ {
	$collect_mode = <both>;
	$i = 0;
    }
    when $line ~~ /PISCINE \s DES \s VER.*/ {
	$collect_mode = <vernets>;
	$i = 0;
    }
    when $line ~~ /PISCINE \s DE \s VA.*/ {
	$collect_mode = <varembe>;
	$i = 0;
    }
    when $line ~~ /PAT / {
	$collect_mode = <patinoire>;
    }
    when $line ~~ m/ ^^
$<ver_open>=([
             | 'Ferm' .
             | \d+h\d+ \s+ '-' \s+ \d+h\d+
             ])

\s+

$<varem_open>=([
               | 'Ferm' .
               | \d+h\d+ \s+ '-' \s+ \d+h\d+
               ])
 $$ /
    {
	if $collect_mode eq <both> {
	    %vernets{@current_dates[$i]} = "$<ver_open>";
	    %varembe{@current_dates[$i]} = "$<varem_open>";
	    $i++;
	}
    }
    when $line ~~ m/ ^^
    $<open>=([
             | 'Ferm' .
             | \d+h\d+ \s+ '-' \s+ \d+h\d+
             ]) /
    {
	given $collect_mode {
	    when <vernets> { %vernets{@current_dates[$i]} = "$<open>"; }
	    when <varembe> { %varembe{@current_dates[$i]} = "$<open>"; }
	}
	$i++;
    }
}

say "Opening hours for Geneva swimming pools";
say "Date: $requested_date";
say "================";
say "Piscine des Vernets: " ~ %vernets{$requested_date};
say "Piscine de Varembe : " ~ %varembe{$requested_date};